[SOLVED] Save Slot Color Change for a Route

[henne]

Hello there,

So, I was thinking about changing the color(s)/image of the save slot when someone reaches a certain route in my game.

Normally, I would just use some if/else (will still do that, I guess?) but I realized that I cannot find the image inside my screens.rpy or somewhere else to make use of variables. I use the standard saving screen with some slight modifications to its look but aside from that it's pretty much the original one, so I am a bit confused where to place my stuff in this case?

So it's it kind of like this:

Code: Select all

### Somewhere in the game:

label somewhere_in_the_game:

  $ normalsave = "whatever the new one is called"       

   "text text text"

What do I do after using that:
https://www.renpy.org/doc/html/config.h ... _callbacks

Code: Select all

default normalsave = "whatever it is called"

init python:

    def altcolor_save(d):
        d["normalsave"] = normalsave

    config.save_json_callbacks.append(altcolor_save)

[Ocelot]

USe FileJson function:
https://www.renpy.org/doc/html/screen_a ... l#FileJson

Modifying standard file_slots screen:

Code: Select all

button:
    action FileAction(slot)

    if FileJson(slot, "normalsave") == "whatever it is called":
        background "#F00"
    else:
        background "#0F0"

    has vbox

    add FileScreenshot(slot) xalign 0.5

    text FileTime(slot, format=_("{#file_time}%A, %B %d %Y, %H:%M"), empty=_("empty slot")):
        style "slot_time_text"

    text FileSaveName(slot):
        style "slot_name_text"

    key "save_delete" action FileDelete(slot)

[henne]

I see, thanks a lot

For some reason I didn't think that it would just be the "background", so I was unsure what to do with all of that.