How to do rolling credits in Ren'Py

[thelastsecret]

I thought that might be a time saver for some Ren'Py programmers:

If you want to add some rolling credits (or any text scrolling through) to your game, here's how you can do that easily:

Code: Select all

label finalcredits:
    scene black
    show screen creditscreen
    pause 100 # or however long it takes to scroll through in a reasonable speed
    pause
    hide screen creditscreen
    return

screen creditscreen:
    vbox:
        xsize 1000 # horizontal size of the credits
        ysize 5500 # how much vertical space your rolling credits take.
        xalign 0.5
        yalign 0.0
        at transform:
            subpixel True
            easein 100: # or however long it takes to scroll through in a reasonable speed
                yalign 1.0
        vbox:
            ysize 720 # enter vertical resolution, so that it starts with an empty screen
        text "Sweet Science":
            font "FredokaOne-regular.ttf"
            color "#F9A"
            size 100
            xalign 0.5
        text "The Girls of Silversee Castle":
            font "FredokaOne-regular.ttf"
            color "#79F"
            size 50
            xalign 0.5
        text ""
        text "Made with Ren'Py.":
            font "ZCOOLXiaoWei-Regular.ttf"
            bold True
            xalign 0.5
        vbox:
            ysize 100 # some empty space in between
        add "a/a cg piano.png": # adding a picture in-between the text
            zoom 0.75
            xalign 0.5
        text "Music credits:":
            font "ZCOOLXiaoWei-Regular.ttf"
            bold True
            xalign 0.5
	text "......." # add all your credits here

This is taken from one of my games. Feel free to use and modify it.

Hope it helps!