[Solved] Can you put an ATL transform on a bar?

[floweringOrchid]

Hi! I'm trying to create a bar within a screen and want it to move/animate on an ATL transform.
For example, I'd like this:

Code: Select all

bar value AnimatedValue(charFriendship, range = 10) xalign 0.5 yalign 0.5:
            top_bar "gui/bar/friendshipBar_empty.png"
            bottom_bar "gui/bar/friendshipBar_filled.png"
            thumb "gui/bar/friendshipBar_thumb.png"
            thumb_offset 10

to act like when this imagebutton moves with a transform at the end:

Code: Select all

imagebutton auto "gui/buttonInteract_%s.png" action [Jump('test')] xalign 0.5 yalign 0.5 at object_float

I've tried looking around for language that could help me in this and haven't found anything. Is there a way I can go about moving a bar on the screen?

[Imperf3kt]

I believe you'll need to use a CDD, creator defined displayable.
I don't have any experience using these, so cannot help more than this, sorry.

[Alex]

... Is there a way I can go about moving a bar on the screen?

Just use transform as you did for imagebutton. Try

Code: Select all

transform bar_transform(t=0.5):
    0.5
    parallel:
        linear t * (config.screen_width / config.screen_height) xalign 1.0
        linear t * (config.screen_width / config.screen_height) xalign 0.0
        repeat
    parallel:
        linear t * (config.screen_height / config.screen_width) yalign 0.0
        linear t * (config.screen_height / config.screen_width) yalign 1.0
        repeat

screen test_bar():
    modal True
    default bar_value = 0
    # mousewheel will change bar value
    key 'mousedown_4' action SetScreenVariable('bar_value', min(20, bar_value + 1))
    key 'mousedown_5' action SetScreenVariable('bar_value', max(0, bar_value - 1))
    key 'mousedown_1' action Hide('test_bar')

    bar value bar_value range 20:
        xsize 200
        align (0.5, 0.5)
        at bar_transform(5.0)

    text "Click to continue" align (0.5, 0.05)

label start:
    "..."
    show screen test_bar
    "?!"
    "done"

[floweringOrchid]

Just use transform as you did for imagebutton. Try

Code: Select all

transform bar_transform(t=0.5):
    0.5
    parallel:
        linear t * (config.screen_width / config.screen_height) xalign 1.0
        linear t * (config.screen_width / config.screen_height) xalign 0.0
        repeat
    parallel:
        linear t * (config.screen_height / config.screen_width) yalign 0.0
        linear t * (config.screen_height / config.screen_width) yalign 1.0
        repeat

Thank you so much, this worked! I will definitely need to keep researching the language more too, as I'm a little confused as to why the usual ATL didn't work with it.

[floweringOrchid]

I believe you'll need to use a CDD, creator defined displayable.
I don't have any experience using these, so cannot help more than this, sorry.

Thanks for your reply as well! I didn't know this was a thing, so I'll have to look into this too