The text in the dictionary is not translated (Solved)

[K_strum]

Hello.
I have the following problem. The text from the dictionary is not translated. I have the following code:

Code: Select all

define items_db = {
    'sigarett': {
        'name': _("Цигарка"),
        'mind': _('Зменшує стрес на 30%'),
        'mind2': _('Можливо трохи зменшить стрес.'),
        'desk': _("Пом'ята й стара. Здається, її ще можна використати."),
        'desk2': _("Від одної думки про те що це опинеться у роті нудить."),
        'image': "images/items/sigarett_simple.png",
        },
        }

And this is a translation that, in theory, should work, but doesn't. Instead of a translation, you get an untranslated text.

Code: Select all

translate english strings:

    # game/script/item.rpy:2
    old "Цигарка"
    new "Cigarette"

    # game/script/item.rpy:2
    old "Зменшує стрес на 30%"
    new "Reduces stress by 30%"

    # game/script/item.rpy:2
    old "Можливо трохи зменшить стрес."
    new "Might reduce stress slightly."

    # game/script/item.rpy:2
    old "Пом'ята й стара. Здається, її ще можна використати."
    new "Old and crumpled. Looks like it still can be used."

    # game/script/item.rpy:2
    old "Від одної думки про те що це опинеться у роті нудить."
    new "Just a thought about putting it in the mouth is sickening."

The only way I have now is to create a separate dictionary for another language, but I would like to find a more convenient option.

[Ocelot]

How do you display your text?
It should be something like: text items_db['sigarett']['name'] or similar. If you are using text interpolation, you need to mark interpolated data as needing translation:

Code: Select all

$ item_name = items_db['sigarett']['name']
text "Name: [item_name!t]" # Notice the !t here.

[K_strum]

How do you display your text?
It should be something like: text items_db['sigarett']['name'] or similar. If you are using text interpolation, you need to mark interpolated data as needing translation:

Code: Select all

$ item_name = items_db['sigarett']['name']
text "Name: [item_name!t]" # Notice the !t here.

That's exactly how I use it. Thank you, it worked!