Disable and enable Saves [SOLVED]

[neometalero]

I need a way to disable and enable the save screen on the game. There is any way I could do this?

[m_from_space]

I need a way to disable and enable the save screen on the game. There is any way I could do this?

There is a variable for this purpose:

Code: Select all

# disable access to the game menu:
$ _game_menu_screen = None

# reset access to the game menu:
$ _game_menu_screen = "save"

[neometalero]

I need a way to disable and enable the save screen on the game. There is any way I could do this?

There is a variable for this purpose:

Code: Select all

# disable access to the game menu:
$ _game_menu_screen = None

# reset access to the game menu:
$ _game_menu_screen = "save"

That worked, but still I can save the game from the little bar on the bottom of the screen. Any way to disable that?

[jeffster]

That worked, but still I can save the game from the little bar on the bottom of the screen. Any way to disable that?

You can use Displayable Inspector: point that little bar with the mouse and press Shift-i.

You could see that it's screen quick_menu.

Examine the file screens.rpy looking for "quick_menu".

You will find:

Code: Select all

screen quick_menu():

    ## Ensure this appears on top of other screens.
    zorder 100

    if quick_menu:

        hbox:
            style_prefix "quick"

            xalign 0.5
            yalign 1.0

            textbutton _("Back") action Rollback()
            textbutton _("History") action ShowMenu('history')
            textbutton _("Skip") action Skip() alternate Skip(fast=True, confirm=True)
            textbutton _("Auto") action Preference("auto-forward", "toggle")
            textbutton _("Save") action ShowMenu('save')
            textbutton _("Q.Save") action QuickSave()
            textbutton _("Q.Load") action QuickLoad()
            textbutton _("Prefs") action ShowMenu('preferences')

Here "if quick_menu:" means that you can turn off that bar with

Code: Select all

    $ quick_menu = False

and switch it back on with

Code: Select all

    $ quick_menu = True

Apart from that, you can change the lines

Code: Select all

            textbutton _("Save") action ShowMenu('save')
            textbutton _("Q.Save") action QuickSave()

to

Code: Select all

            if save_on:
                textbutton _("Save") action ShowMenu('save')
                textbutton _("Q.Save") action QuickSave()

Set that variable to normally allow saves:

Code: Select all

default save_on = True

And you could hide those textbuttons ("Save", "Q.Save") with

Code: Select all

    $ save_on = False

[neometalero]

I managed to hide and activate the save when needed. I will play around a little bit more and see if I can do it in a more elegant way, but this was all of the information I needed. Thanks a lot for your help! Both of you!