Different bleeps for 1 character?

[Zapor]

Hello anyone!

I am use character bleeps method, simular to undertale etc, but i notised what sounds... not alwayse related character images.

i mean, you can use tags for images like "Girl happy", "Girl mad" etc.
And in game it work perfect.

girl happy " Hello!"
girl mad "Arrgh!"

but, when it come to bleeps sounds, it alwayse a same!

Code: Select all

def Stelbeep(event, **kwargs):
        if event == "show":
            renpy.sound.play("audio/St.wav", loop = True)
        elif event == "slow_done" or event == "end":
            renpy.sound.stop()

It is how it work right now. But i want use character tags for select different bleeps! Like:

Code: Select all

def Stelbeep(event, **kwargs):
        if event == "show":
            if character tag == "happy":
                renpy.sound.play("audio/happy.wav", loop = True)
            elif character tag == "sad":
                renpy.sound.play("audio/sad.wav", loop = True)
        elif event == "slow_done" or event == "end":
            renpy.sound.stop()

But i not know where i can find characters tags and use it! maybe i can use Voice tag for this? or try grab info from image tags?

[Vladya]

You need _side_image_attributes variable.
This is a tuple of strings (or None), where the first element is the image tag associated with the character, and the subsequent elements are the attributes passed along with the name (exactly what you are looking for).

Example:

Code: Select all

init python:

    def char_callback(event, *args, **kwargs):

        if event == "show":

            _image_tag = char_tag = None
            if _side_image_attributes:
                _image_tag = _side_image_attributes[0]
                char_tag = ' '.join(_side_image_attributes[1:])

            if char_tag == "happy":
                renpy.sound.play("audio/happy.wav", loop=True)
            elif char_tag == "sad":
                renpy.sound.play("audio/sad.wav", loop=True)
            else:
                renpy.sound.play("audio/default.wav", loop=True)

        elif event in ("slow_done", "end"):
            renpy.sound.stop()

[Zapor]

Thank you, it really working!