Tooltips for Nav and Another Menu appear in both tooltip boxes

[Avior]

Sorry if my title doesn't make sense, I struggled a little bit to summarize it concisely. :v

So my project has an inventory menu, which uses the navigation menu. Both the navigation menu and the inventory menu use tooltips, which are working just fine individually, however displaying both menus at the same time is causing issues.

Basically, the tooltips for each menu have a box where they're supposed to appear, but when the two menus are displayed together, the tooltips for both menus show up in both boxes. I can gather that this happens because this code:

Code: Select all

    $ tooltip = GetTooltip()

    if tooltip:
        text "[tooltip]" xpos 736 ypos 548 size 17

is defined under the same name for both menus, with different coordinates, so both menus read both instances of it. I've tried creating two different tooltip sets, for example:

Code: Select all

    $ tooltip = GetTooltip()

    if tooltip:
        text "[tooltip]"

    $ tooltip2 = GetTooltip()

    if tooltip2:
        text "[tooltip]"

This sort of works; it shows the applicable tooltip in the correct box and "none" in the other, though it also causes some errors where moving from one button to another causes the tooltips for those buttons to appear in both boxes and swap back and forth.

Basically, what I'm seeing is that I don't really understand the tooltip function well enough to figure it out at this point, haha.


Here's some screenshots to demonstrate the problem: (please ignore how horrible it looks; my game uses pixel art but I had to downsize the images for the forum)

This is one of the nav menu tooltips displayed by itself.


And one of the inventory menu tooltips with both menus open.

And here's the relevant code: ("phone_menu" is the nav menu.)

Code: Select all

screen inventory_menu:
    tag menu
    use phone_menu

    $ tooltip = GetTooltip()

    if tooltip:
        text "[tooltip]" xpos 736 ypos 548 size 17

    imagebutton:
        hover "gui/inv_osphone.png"
        idle "gui/inv_osphone.png"
        action NullAction()
        xpos 733
        ypos 283
        tooltip "{b}Ospina's Phone{/b}\nA smartphone you can wear on your wrist. The screen \nis cracked and the battery is dead, so it’s pretty useless \nright now."

Code: Select all

screen phone_menu:
    tag menu

    $ tooltip = GetTooltip()

    if tooltip:
        text "[tooltip]" xpos 468 ypos 578 size 17

    imagebutton:
        auto "gui/phone_return_%s.png"
        action SetVariable('qm_use', True), Return()
        xpos 538
        ypos 319
        tooltip "Return to surviving."

Any help in sorting this out would be greatly appreciated!

[gas]

You got everything right, the issue is how bad Tooltips are. And multiple Tooltips are even worst (so I usually suggest people to avoid them).
Having two Tooltips objects differently named was the 'solution', but as you can see it's prone to bugs the same.

What you are experiencing is an engine glitch that you can't solve.
You should rethink the interface.

One idea is to use for the phone buttons an 'hovered' action that show another screen, with text inside, actually faking the Tooltip system.

Code: Select all

screen phone_menu:
    tag menu

    imagebutton:
        auto "gui/phone_return_%s.png"
        action [SetVariable('qm_use', True), Return()] 
        hovered Show("ex_tooltip", ttext = "Return to surviving.") 
        unhovered Hide("ex_tooltip")
        xpos 538
        ypos 319

screen ex_tooltip(ttext):
    text "[ttext]"  xpos 468 ypos 578 size 17

This create a fake tooltip. Just repeat the logic for all phone buttons, passing a different text. That way you have just one real tooltip (the invenntory one) that shouldn't be prone to bugs by pairing with others.

Mind that's not the optimal solution, but it should work the way you want.

[Imperf3kt]

I'd just use the one if tool tip and below that, add a further conditional which is set based on the button hovered. If the variable isn't true, the tool tip won't show, if it is, it will.

[Avior]

One idea is to use for the phone buttons an 'hovered' action that show another screen, with text inside, actually faking the Tooltip system.

Code: Select all

screen phone_menu:
    tag menu

    imagebutton:
        auto "gui/phone_return_%s.png"
        action [SetVariable('qm_use', True), Return()] 
        hovered Show("ex_tooltip", ttext = "Return to surviving.") 
        unhovered Hide("ex_tooltip")
        xpos 538
        ypos 319

screen ex_tooltip(ttext):
    text "[ttext]"  xpos 468 ypos 578 size 17

This create a fake tooltip. Just repeat the logic for all phone buttons, passing a different text. That way you have just one real tooltip (the invenntory one) that shouldn't be prone to bugs by pairing with others.

It's a little disappointing that they're bugged like that, but this seems like a workable solution. If I can't figure out a cleaner way, I'll give it a try, thanks!

I'd just use the one if tool tip and below that, add a further conditional which is set based on the button hovered. If the variable isn't true, the tool tip won't show, if it is, it will.

Thanks for the suggestion! I gave this a shot, and I've gotten a little closer to the intended result but there's still a bit of an issue.

Here's the code for the nav menu:

Code: Select all

    $ tooltip = GetTooltip()

    if tooltip_p:
        if tooltip:
            text "[tooltip]" xpos 468 ypos 578 size 17

    imagebutton:
        auto "gui/phone_return_%s.png"
        hovered SetVariable("tooltip_p", "True")
        unhovered SetVariable("tooltip_p", "False")
        action SetVariable('qm_use', True), Return()
        xpos 538
        ypos 319
        tooltip "Return to surviving."

And the code for the inventory menu:

Code: Select all

    $ tooltip = GetTooltip()

    if tooltip_i:
        if tooltip:
            text "[tooltip]" xpos 736 ypos 548 size 17

    imagebutton:
        hover "gui/inv_osphone.png"
        idle "gui/inv_osphone.png"
        hovered SetVariable("tooltip_i", "True")
        unhovered SetVariable("tooltip_i", "False")
        action NullAction()
        xpos 733
        ypos 283
        tooltip "{b}Ospina's Phone{/b}\nA smartphone you can wear on your wrist. The screen \nis cracked and the battery is dead, so it’s pretty useless \nright now."

I added a variable to trigger the tooltip for each menu, and assigned it to each button with hovered/unhovered. The hover/unhover actions are triggering the variables just fine, but it seems like the screens only evaluate the if statement once. So, when you scroll over a button, the tooltip displays only in its correct box, but every button hovered after that will display in both boxes again, even though the variables are correct. Any ideas on how to get it to evaluate the if statement each time?

[Imperf3kt]

Unfortunately, no, I couldn't say.
You understood my hurriedly blurted out thoughts pretty well, but I was unsure if they'd work. Theoretically, it should, but I haven't had a chance to test.

What I'd recommend is swapping the tool tip and tool tip p conditionals. You want the tool tip check first, then to check which variable is true (so you can determine if the tool tip appears, or if it stays hidden.


I'll add this to an ever growing list of examples of what I had in mind I have promised people.
Hopefully, tonight I will finally have a chance to sit down at my computer and get a round tuit

[Avior]

What I'd recommend is swapping the tool tip and tool tip p conditionals. You want the tool tip check first, then to check which variable is true (so you can determine if the tool tip appears, or if it stays hidden.

Gave it a shot, but doesn't seem to have changed anything. I've fiddled with it some more but I'm thinking at this point there's probably not a viable fix. I think I'll go with gas' initial suggestion and pass one menu's tool tips as screens; it's not ideal but I've definitely written worse code!

Thanks to both of you for your help!

[Imperf3kt]

I will definitely still look into this once I have some time / fix my PC.

If I come up with something workable, I'll pass it along.

[philat]

There is an obvious solution in the docs...

https://www.renpy.org/doc/html/screen_a ... GetTooltip

Code: Select all

screen tooltip1():
    $ tooltip = GetTooltip("tooltip1")
    vbox:
        xalign 0.0
        textbutton "hover1" action NullAction tooltip "screen1"
        if tooltip:
            text tooltip

screen tooltip2():
    $ tooltip = GetTooltip("tooltip2")
    vbox:
        xalign 1.0
        textbutton "hover2" action NullAction tooltip "screen2"
        if tooltip:
            text tooltip