[Solved] Moving the Options Buttons back in Place

[Zodiac_Stories]

Howdy~ I am very new to Ren'Py, and I've been following some tutorials but seem to have run into a problem.

I managed to move the title screen option bottoms,
Screenshot Example: https://sta.sh/0n9vbe0x7wr

But when you go into one of the menus like preference, load/saving file, help, etc., the option are still in the same spot and over over lapping.
Screenshot Example:
https://sta.sh/01dy8y7etw96
https://sta.sh/0qor9g06cf3
https://sta.sh/01na3ku8a18l

Is there a way to fix this? The tutorial I watched was a little old, and didn't show how to fix this problem on the main title screen, only when you are in the game.

Thanks in advanced.

[jeffster]

In file "screens.rpy" there is "screen main_menu".
It has a line "use navigation".
"screen navigation" is used in Main Menu and in Game Menu.
Therefore if you change anything related to "screen navigation", it shows in all menu screens of Main Menu and Game Menu.

The easiest way to change the title screen but not affect other screens is to replace "use navigation" in "screen main_menu" with some custom layout. For example:

Code: Select all

screen main_menu():
    tag menu

    add gui.main_menu_background

    frame:
        style "main_menu_frame"

    #use navigation WAS HERE :-)
    vbox:
        textbutton _("Start") action Start()
        textbutton _("Load") action ShowMenu("load")
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("About") action ShowMenu("about")

        if renpy.variant("pc") or (renpy.variant("web") and not renpy.variant("mobile")):
            textbutton _("Help") action ShowMenu("help")

        if renpy.variant("pc"):
            textbutton _("Quit") action Quit(confirm=not main_menu)

Then you can add some "style" to this vbox and change its position etc., for example:

Code: Select all

    #use navigation
    vbox:
        pos (1000, 600)
        textbutton _("Start") action Start()
        #...and so on

[jeffster]

Here is an example:


"gui.main_menu_background" in file "gui.rpy" is set to the background that you see in the screenshot.
The screens "navigation" and "game_menu" are left unchanged.
The "main_menu" screen is (vbox is changed to hbox, as another example of possible modifications):

Code: Select all

screen main_menu():
    tag menu
    add gui.main_menu_background
    hbox:
        style_prefix "title_menu"
        textbutton _("Start") action Start()
        textbutton _("Load") action ShowMenu("load")
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("About") action ShowMenu("about")
        if renpy.variant("pc") or (renpy.variant("web") and not renpy.variant("mobile")):
            textbutton _("Help") action ShowMenu("help")
        if renpy.variant("pc"):
            textbutton _("Quit") action Quit(confirm=not main_menu)

    if gui.show_name:
        vbox:
            style "main_menu_vbox"
            text "[config.name!t]":
                style "main_menu_title"
            text "[config.version]":
                style "main_menu_version"

style title_menu_hbox:
    align (0.5, 0.0)
    spacing 24

style title_menu_button_text:
    color "#CC9"
    hover_color "#FFC"
    outlines [(3, "#3333")]
    size 64

[Zodiac_Stories]

In file "screens.rpy" there is "screen main_menu".
It has a line "use navigation".
"screen navigation" is used in Main Menu and in Game Menu.
Therefore if you change anything related to "screen navigation", it shows in all menu screens of Main Menu and Game Menu.

The easiest way to change the title screen but not affect other screens is to replace "use navigation" in "screen main_menu" with some custom layout. For example:

Code: Select all

screen main_menu():
    tag menu

    add gui.main_menu_background

    frame:
        style "main_menu_frame"

    #use navigation WAS HERE :-)
    vbox:
        textbutton _("Start") action Start()
        textbutton _("Load") action ShowMenu("load")
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("About") action ShowMenu("about")

        if renpy.variant("pc") or (renpy.variant("web") and not renpy.variant("mobile")):
            textbutton _("Help") action ShowMenu("help")

        if renpy.variant("pc"):
            textbutton _("Quit") action Quit(confirm=not main_menu)

Then you can add some "style" to this vbox and change its position etc., for example:

Code: Select all

    #use navigation
    vbox:
        pos (1000, 600)
        textbutton _("Start") action Start()
        #...and so on

Thanks! It works wonderfully

[Zodiac_Stories]

Here is an example:


"gui.main_menu_background" in file "gui.rpy" is set to the background that you see in the screenshot.
The screens "navigation" and "game_menu" are left unchanged.
The "main_menu" screen is (vbox is changed to hbox, as another example of possible modifications):

Code: Select all

screen main_menu():
    tag menu
    add gui.main_menu_background
    hbox:
        style_prefix "title_menu"
        textbutton _("Start") action Start()
        textbutton _("Load") action ShowMenu("load")
        textbutton _("Preferences") action ShowMenu("preferences")
        textbutton _("About") action ShowMenu("about")
        if renpy.variant("pc") or (renpy.variant("web") and not renpy.variant("mobile")):
            textbutton _("Help") action ShowMenu("help")
        if renpy.variant("pc"):
            textbutton _("Quit") action Quit(confirm=not main_menu)

    if gui.show_name:
        vbox:
            style "main_menu_vbox"
            text "[config.name!t]":
                style "main_menu_title"
            text "[config.version]":
                style "main_menu_version"

style title_menu_hbox:
    align (0.5, 0.0)
    spacing 24

style title_menu_button_text:
    color "#CC9"
    hover_color "#FFC"
    outlines [(3, "#3333")]
    size 64

Thanks!

[jeffster]

You are welcome.